怎样在sql中把字符串a,b,c,d用while依次输出a b c d
怎样在sql中把字符串a,b,c,d用while依次输出
a
b
c
d
我想转换为数组后输出，找了一下好像没有spit方法
[解决办法]
为什么要用WHILE 直接字符集的拆分多好.
[解决办法]
--参考
拆分表:
--> --> (Roy)生成測試數據
if not object_id('Tab') is null
drop table Tab
Go
Create table Tab([Col1] int,[COl2] nvarchar(5))
Insert Tab
select 1,N'a,b,c' union all
select 2,N'd,e' union all
select 3,N'f'
Go
--SQL2000用辅助表:
if object_id('Tempdb..#Num') is not null
drop table #Num
go
select top 100 ID=Identity(int,1,1) into #Num from syscolumns a,syscolumns b
Select
a.Col1,COl2=substring(a.Col2,b.ID,charindex(',',a.Col2+',',b.ID)-b.ID)
from
Tab a,#Num b
where
charindex(',',','+a.Col2,b.ID)=b.ID --也可用 substring(','+a.COl2,b.ID,1)=','
--2000不使用辅助表
Select
a.Col1,COl2=substring(a.Col2,b.number,charindex(',',a.Col2+',',b.number)-b.number)
from
Tab a join master..spt_values b
ON B.type='p' AND B.number BETWEEN 1 AND LEN(A.col2)
where
substring(','+a.COl2,b.number,1)=','
SQL2005用Xml:
select
a.COl1,b.Col2
from
(select Col1,COl2=convert(xml,'<root><v>'+replace(COl2,',','</v><v>')+'</v></root>') from Tab)a
outer apply
(select Col2=C.v.value('.','nvarchar(100)') from a.COl2.nodes('/root/v')C(v))b
SQL05用CTE:
;with roy as
(select Col1,COl2=cast(left(Col2,charindex(',',Col2+',')-1) as nvarchar(100)),Split=cast(stuff(COl2+',',1,charindex(',',Col2+','),'') as nvarchar(100)) from Tab
union all
select Col1,COl2=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from Roy where split>''
)
select COl1,COl2 from roy order by COl1 option (MAXRECURSION 0)
生成结果:
/*
Col1 COl2
----------- -----
1 a
1 b
1 c
2 d
2 e
3 f
*/
with tb(id, column_A) as (
select 1, '1,2,3' union all
select 2, '3,4' union all
select 3, '1,3')
,td as(
select id,SUBSTRING(column_A,number,CHARINDEX(',',column_a+',',number)-number) b
from tb,master..spt_values where type='p' and number>0 and SUBSTRING(','+column_A,number,1)=',')
select * from td
declare @sql varchar(20)
set @sql='a,b,c,d'
declare @s varchar(5)
set @sql=@sql+','
while charindex(',',@sql)>0
begin
select @s=substring(@sql,1,charindex(',',@sql)-1)
select @sql=substring(@sql,charindex(',',@sql)+1,len(@sql))
print @s
end
--结果
a
b
c
d
declare @s varchar(255),@i int
set @s='a,b,c,d'
set @i=charindex(',',@s)
while @i>0
begin
print left(@s,@i-1)
set @s=right(@s,len(@s)-@i)
set @i=charindex(',',@s)
end
print @s
