ADO储存图片到sql数据库中,二进制流变量的表示

ADO存储图片到sql数据库中,二进制流变量的表示
Dim cnn As New ADODB.Connection
Dim ADOre As New ADODB.Recordset       '声明ADO数据集对象
Dim ADOst As New ADODB.Stream          '声明ADO数据流对象
Set ADOre = New ADODB.Recordset        '创建ADO数据集对象
Set ADOst = New ADODB.Stream           '创建ADO数据流对象
ADOst.Mode = adModeReadWrite           '设置数据流修改数据模式属性为可读写
ADOst.Type = adTypeBinary              '设置数据流中的数据类型为二进制
Dim aa
ADOst.Open                   '打开数据流对象
ADOst.LoadFromFile ThisWorkbook.Path & "" & "TU1.jpg"      '把图片文件载入对象
cnn.ConnectionString = "Provider=SQLOLEDB;" _
        & "server=127.0.0.1;" _
        & "User ID=sa;" _
        & "Password =qwe;" _
        & "DNS=mydns;" _
        & "Initial Catalog =mydate"
    cnn.Open
    aa = ADOst.Read()
 Sql = "insert into p_all_table(picture) values('" & aa & "')"
提示字符串后' ???? ' 引号不完整.cnn.Execute Sql
ADOre.Update     '更新数据集对象
ADOre.Close      '关闭数据集对象
可能是二进制的长度太长了,那么如果用insert into  vlaues() 语句,那么 变量aa应该怎么表示?
[解决办法]
使用流对象保存和显示图片 
打开vb6,新建工程。

添加两个按钮,一个image控件
注意:Access中的photo字段类型为OLE对象.
SqlServer中的photo字段类型为Image

'** 引用 Microsoft ActiveX Data Objects 2.5 Library 及以上版本
‘2.5版本以下不支持Stream对象
Dim iConcstr As String
Dim iConc As ADODB.Connection
 

'保存文件到数据库中
Sub s_SaveFile()
    Dim iStm As ADODB.Stream
    Dim iRe As ADODB.Recordset
    Dim iConcstr As String

    '读取文件到内容
    Set iStm = New ADODB.Stream
    With iStm
        .Type = adTypeBinary   '二进制模式
        .Open
        .LoadFromFile App.Path + "\test.jpg"
    End With
   

    '打开保存文件的表
    Set iRe = New ADODB.Recordset
    With iRe
        .Open "select * from img", iConc, 1, 3
        .AddNew         '新增一条记录
        .Fields("photo") = iStm.Read
        .Update
    End With
   

   '完成后关闭对象
    iRe.Close
    iStm.Close
End Sub


Sub s_ReadFile()
    Dim iStm As ADODB.Stream
    Dim iRe As ADODB.Recordset
    '打开表
Set iRe = New ADODB.Recordset
‘得到最新添加的纪录
    iRe.Open "select top 1 * from img order by id desc", iConc, adOpenKeyset, adLockReadOnly
    '保存到文件
    Set iStm = New ADODB.Stream
    With iStm
        .Mode = adModeReadWrite
        .Type = adTypeBinary
        .Open
        .Write iRe("photo")
‘这里注意了,如果当前目录下存在test1.jpg,会报一个文件写入失败的错误.
        .SaveToFile App.Path & "\test1.jpg"
    End With
   

    Image1.Picture = LoadPicture(App.Path & "\test1.jpg")
   '关闭对象
    iRe.Close
    iStm.Close
End Sub
 

Private Sub Command1_Click()
Call s_ReadFile
End Sub


Private Sub Command2_Click()
Call s_SaveFile
End Sub


Private Sub Form_Load()
    '数据库连接字符串
    iConcstr = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
        ";Data Source=F:\csdn_vb\database\保存图片\access图片\img.mdb"

‘下面的语句是连接sqlserver数据库的.
    ‘iConcstr = "Provider=SQLOLEDB.1;Persist Security Info=True;" & _
‘ "User ID=sa;Password=;Initial Catalog=test;Data Source=yang"
 

   Set iConc = New ADODB.Connection
   iConc.Open iConcstr
End Sub
 

Private Sub Form_Unload(Cancel As Integer)
iConc.Close
Set iConc = Nothing
End Sub